;LEAGUE OF LEGENDS CREEP TIMERS - MINIMALIST VERSION
;VERSION 2.2
;Created by unknown, modded by theMizzler
;Minimal version created by pacov
;Slightly altered by Headchopperz, added inhib and ward
;Last update - 5/29/2012

;DESCRIPTION
;The purpose of this AutoHotKey script is to enable League of Legends players to quickly track when critical creeps are spawned.
;The script handles baron, dragon, red, and blue buffs.  In short, the user with this script installed presses a hotkey (detailed
;below) to track when a specific creep has died.  When the user presses the hotkey, a chat message is sent indicating the respawn
;time of those specific creeps.  The bottom line is that this script makes it simple for everyone on the team to know when creeps
;respawn just by having 1 person paying enough attention to press a hot key when a particular creep dies.

;HOW TO INSTALL
;Step 1 - Download and install AutoHotkey at http://www.autohotkey.com/download/
;Step 2 - If you received this code via pastebin, open notepad, copy and paste the info, and save the file as whatever you want.
;be sure to save the file with the extension .ahk (ex lol.ahk).  If you received this file as a .ahk file, move to step 3.

;HOW TO RUN
;Right click on the .ahk file and click run.  If you compiled the script, simply click on the compiled file and it will execute.

;HOW TO USE IN GAME
;The following step is CRITICAL.  At 15 seconds into the game, you MUST press f9.  This sets the internal counter within the
;script so that the script believes your game time is currently at 15 seconds.  You have to do this at the start of every game
;and it is not possible to automate it further.  The thing to understand here is that the script has NO idea of when your game
;has started unless you tell it (by pressing f9 at 15 seconds).  When you are done playing, be sure to press F10 to stop the
;timers

;This variable determines when in game to press the F9 key to synchronize the time of the script and the game, in seconds.
clockSynchroniseTime = 15

;These variables determine what to call the objectives
ourBlue     = oB
ourRed      = oR
theirBlue   = tB
theirRed    = tR
dragon      = Drag
baron       = Baron
ward	    = Ward
inhib	    = Inhib

;HOTKEYS
;F9 = Reset game timer to 15 seconds(Use this after 15 seconds ingame.)
;F10 = Stop all timers (Use this when you finish the game)

;F1 = OUR BLUE
;F2 = OUR RED
;F3 = THEIR BLUE
;F4 = THEIR RED
;F5 = DRAGON
;F6 = BARON NASH
;F7 = Ward
;F8 = Inhib

;Everything below this line is the script for the game.  Good luck and have fun!




#Persistent

globalSeconds := 0

MakeTime(totalSeconds) {
    S := mod(totalSeconds, 60)
    M := mod((totalSeconds // 60), 60)
    H := mod((totalSeconds // 3600), 3600)

    zM := ""
    zS := ""
    zH := ""

    if M < 10
    	zM := "0"
    if S < 10
    	zS := "0"
    if H > 0
        zH := H . ":"

    return (zH . zM . M . ":" . zS . S)
}

TimeStamp(name, delay) {
    global globalSeconds

    delayS := globalSeconds + delay

    Chat(MakeTime(delayS) . " " . name)
}

~F1::
    TimeStamp(ourBlue, 300)
return

~F2::
    TimeStamp(ourRed, 300)
return

~F3::
    TimeStamp(theirBlue, 300)
return

~F4::
    TimeStamp(theirRed, 300)
return

~F5::
    TimeStamp(dragon, 360)
return

~F6::
    TimeStamp(baron, 420)
return

~F7::
    TimeStamp(ward, 180)
return

~F8::
    TimeStamp(inhib, 300)
return

~F9::
    globalSeconds := clockSynchroniseTime
    SetTimer, Update, 1000
return


~F10::
    MsgBox, 0x40000, JungleTimer, JungleTimer Stopped, 0.75
    SetTimer, Update, Off
return

Chat(msg) {
	Send {Enter}
	sleep 50
	Send %msg%
	sleep 50
	Send {Enter}
}

Update:
    globalSeconds += 1
return