AGVD CAD Panel Estimator

; AGVD CAD PANEL ESTIMATOR
;
; www.ArthurGanem.com
;
; up to 100 panels

(prompt "\nLoaded AGVD Panel Estimator! - TRIAL VERSION - NOT FOR COMMERCIAL USE - www.ArthurGanem.com")
(alert "\nLoaded AGVD Panel Estimator! - This is a TRIAL version and is not allowed for commercial use. (Trial version supports up to 100 panels) \n\nFor licensing information e-mail to contact@ArthurGanem.com")

(defun c:esti(/ ss1 ssIndex polyObject vla_poly vla_region mpCenter mpName mpText fileName mpArea mpPerimeter mpFlapArea mpPerimeterCut totalFaceArea totalFlapArea totalPerimeterCut cords mpWidth mpLength)

  (setq ss1 (ssget (list
                  (cons 0 "POLYLINE,LWPOLYLINE")
                  (cons -4 "&")
                  (cons 70 1)
                  )
                )
    )

  (setq ssIndex 0)
  (setq mpName (list))
  (setq mpArea (list))
  (setq mpFlapArea (list))
  (setq mpPerimeterCut (list))
  (setq mpLength (list))
  (setq mpWidth (list))
  (setq totalFaceArea 0.0)
  (setq totalFlapArea 0.0)
  (setq totalPerimeterCut 0.0)

  (setq fileName (getfiled "Where would you like to save TEXT file with panel estimates?" "" "txt" 1))
  (setq fileName (open fileName "w"))
  (write-line "TRIAL VERSION (Trial version supports up to 100 panels) - NOT FOR COMMERCIAL USE - www.ArthurGanem.com\n" fileName)
  (write-line "Panel Name\tPanel Length\tPanel Width\tFace Area\tFlap Area\tTotal Perimeter Cut\n" fileName)

  (vl-load-com)

  (repeat 100
    (setq polyObject (ssname ss1 ssIndex))

    (if (/= polyObject nil)
      (progn

    (setq vla_poly (vlax-ename->vla-object polyObject))

    (setq mpName (append mpName (list (strcat "MP-" (itoa ssIndex)))))

    (progn
      (setq vla_region
         (car (vlax-safearray->list
            (vlax-variant-value
              (vla-addregion
                (vla-objectidtoobject
                  (vla-get-document vla_poly)
                  (vla-get-ownerid vla_poly)
                  )

                (vlax-safearray-fill
                  (vlax-make-safearray vlax-vbobject (cons 0 (1- (length (list vla_poly)))))
                  (list vla_poly)
                  )
                )
              )
            )
              )
        )

      (setq mpCenter (vlax-safearray->list
               (vlax-variant-value
                 (vla-get-centroid vla_region)
               )
             )
        )

      (vla-delete vla_region)

    ) ; progn

    (setq mpText (vla-addtext (vla-get-modelspace (vla-get-activedocument (vlax-get-acad-object))) (nth ssIndex mpName) (vlax-3d-point mpCenter) 4.5))
    (vla-put-StyleName mpText "Standard")


    (setq cords (vlax-safearray->list(vlax-variant-value (vla-get-coordinates vla_poly))))
    (setq mpLength (append mpLength (list (/ (abs (- (nth 0 cords) (nth 4 cords))) 12))))
    (setq mpWidth (append mpWidth (list (/ (abs (- (nth 1 cords) (nth 5 cords))) 12))))
    (setq mpArea (append mpArea (list (/ (vla-get-Area vla_poly) 144))))
    (setq mpPerimeter (vla-get-Length vla_poly))
    (setq mpFlapArea (append mpFlapArea (list (/ (* mpPerimeter 1.0625) 144))))
    (setq mpPerimeterCut (append mpPerimeterCut (list (+ (nth ssIndex mpArea) (nth ssIndex mpFlapArea)))))

    (write-line (strcat (nth ssIndex mpName) "\t" (rtos (nth ssIndex mpLength) 2) "\t" (rtos (nth ssIndex mpWidth) 2) "\t" (rtos (nth ssIndex mpArea) 2) "\t" (rtos (nth ssIndex mpFlapArea) 2) "\t" (rtos (nth ssIndex mpPerimeterCut) 2)) fileName)

    (setq totalFaceArea (+ totalFaceArea (nth ssIndex mpArea)))
    (setq totalFlapArea (+ totalFlapArea (nth ssIndex mpFlapArea)))
    (setq totalPerimeterCut (+ totalPerimeterCut (nth ssIndex mpPerimeterCut)))

    (setq ssIndex (+ ssIndex 1))

      ))

   )


  (write-line (strcat "\n\nTOTAL FACE AREA:\t\t" (rtos totalFaceArea 2)) fileName)
  (write-line (strcat "TOTAL FLAP AREA:\t\t" (rtos totalFlapArea 2)) fileName)
  (write-line (strcat "TOTAL PERIMETER CUT (AREA):\t" (rtos totalPerimeterCut 2)) fileName)

  (close fileName)

  (prompt "\n-------- TEXT FILE EXPORTED --------")
  (prompt (strcat "\n\nTOTAL FACE AREA:\t\t\t\t " (rtos totalFaceArea 2) "\n" ))
  (prompt (strcat "TOTAL FLAP AREA:\t\t\t\t " (rtos totalFlapArea 2) "\n" ))
  (prompt (strcat "TOTAL PERIMETER CUT (AREA):\t" (rtos totalPerimeterCut 2) "\n" ))

  (princ)
  )